// Copyright (C) 2023 Calcarta
module Calcarta.Calculation.``Cha2ds2-vasc``.Code
open Calcarta.CodeResource.Standard

type Age =
    | [<Name("<65")>] LessThan65 = 0
    | [<Name("65-74")>] Between65and74 = 1
    | [<Name(">=75")>] GreaterThanEqual75 = 2

type Patient ={
    Age : Age

    [<Name("Is female")>]
    IsFemale : bool

    [<Name("Congestive Heart Failure (CHF) history")>]
    ChfHistory : bool

    [<Name("Hypertension history")>]
    HypertensionHistory : bool

    [<Name("Stroke / TIA / thromboembolism history")>]
    StrokeHistory : bool
    
    [<Name("Vascular disease history")>]
    [<Description("Prior MI, peripheral artery disease, or aortic plaques")>]
    VascularDiseaseHistory : bool

    [<Name("Diabetes history")>]
    DiabetesHistory : bool
}

type Output = {
    [<Name("CHA2DS2-VASc score")>]
    Score : decimal

    [<Name("Risk of ischaemic stroke")>]
    IschaemicStrokeRisk : string

    [<Name("Risk of stroke / TIA / systemic embolism")>]
    StrokeRisk : string
}

[<Name("Stroke risk", AppliesTo = Argument.Output)>]
[<Description("", AppliesTo = Argument.Output)>]
[<Unit("Points", AppliesTo = Argument.Output)>]
let ``cha2ds2-vasc`` (patient : Patient) = 
    let score value point = if value then point else 0m
    let agePoints = 
        match patient.Age with
        | Age.LessThan65 -> 0m
        | Age.Between65and74 -> 1m
        | Age.GreaterThanEqual75 -> 2m
        | _ -> 0m
    let cha2ds2vasc = 
        agePoints +
        score patient.IsFemale 1m +
        score patient.ChfHistory 1m +
        score patient.HypertensionHistory 1m +
        score patient.StrokeHistory 2m +
        score patient.VascularDiseaseHistory 1m +
        score patient.DiabetesHistory 1m
    let ischaemicStrokeRisk = 
        match cha2ds2vasc with
        | 0m -> "0.2%"
        | 1m -> "0.6%"
        | 2m -> "2.2%"
        | 3m -> "3.2%"
        | 4m -> "4.8%"
        | 5m -> "7.2%"
        | 6m -> "9.7%"
        | 7m -> "11.2%"
        | 8m -> "10.8%"
        | 9m -> "12.2%"
        | _ -> "Undefined"
    let strokeTiaEmbolismRisk =
        match cha2ds2vasc with
        | 0m -> "0.3%"
        | 1m -> "0.9%"
        | 2m -> "2.9%"
        | 3m -> "4.6%"
        | 4m -> "6.7%"
        | 5m -> "10.0%"
        | 6m -> "13.6%"
        | 7m -> "15.7%"
        | 8m -> "15.2%"
        | 9m -> "17.4%"
        | _ -> "Undefined"
    {
        Score = cha2ds2vasc
        IschaemicStrokeRisk = ischaemicStrokeRisk
        StrokeRisk = strokeTiaEmbolismRisk
    }